/***************************************************************************
* __________ __ ___.
* Open \______ \ ____ ____ | | _\_ |__ _______ ___
* Source | _// _ \_/ ___\| |/ /| __ \ / _ \ \/ /
* Jukebox | | ( <_> ) \___| < | \_\ ( <_> > < <
* Firmware |____|_ /\____/ \___ >__|_ \|___ /\____/__/\_ \
* \/ \/ \/ \/ \/
* $Id$
*
* New greyscale framework
* SH1 assembler routines
*
* This is a generic framework to display 129 shades of grey on low-depth
* bitmap LCDs (Archos b&w, Iriver & Ipod 4-grey) within plugins.
*
* Copyright (C) 2008 Jens Arnold
*
* This program is free software; you can redistribute it and/or
* modify it under the terms of the GNU General Public License
* as published by the Free Software Foundation; either version 2
* of the License, or (at your option) any later version.
*
* This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
* KIND, either express or implied.
*
****************************************************************************/
#include "config.h"
/* Plugins should not normally do this, but we need to check a macro, and
* plugin.h would confuse the assembler. */
.text
.global __grey_line1
.type __grey_line1, @function
#if (LCD_PIXELFORMAT == VERTICAL_PACKING) && (LCD_DEPTH == 1)
/****************************************************************************
* void _grey_line1(int width, r4
* unsigned char *dst, r5
* const unsigned char *src, r6
* const unsigned char *lut); r7
*/
__grey_line1:
mov #1, r0
tst r0, r6
bt .p1_h_end
mov.b @r6+, r0
extu.b r0, r0
mov.b @(r0, r7), r0
add #-1, r4
mov.b r0, @r5
add #8, r5
.p1_h_end:
mov #2, r0
cmp/hs r0, r4
bf .p2_t_end
tst r0, r6
bt .p2_h_end
mov.w @r6+, r1
extu.b r1, r0
mov.b @(r0, r7), r0
shlr8 r1
mov.b r0, @(8, r5)
extu.b r1, r0
mov.b @(r0, r7), r0
add #-2, r4
mov.b r0, @r5
add #16, r5
.p2_h_end:
add #-4, r4
cmp/pz r4
bf .p4_end
add r6, r4
.p4_loop:
mov.l @r6+, r1
swap.w r1, r2
extu.b r2, r0
mov.b @(r0, r7), r0
shlr8 r2
mov.b r0, @(8, r5)
extu.b r2, r0
mov.b @(r0, r7), r2
extu.b r1, r0
mov.b r2, @r5
add #16, r5
mov.b @(r0, r7), r0
shlr8 r1
mov.b r0, @(8, r5)
extu.b r1, r0
mov.b @(r0, r7), r0
cmp/hs r6, r4
mov.b r0, @r5
add #16, r5
bt .p4_loop
/* No need to correct the count, we're only testing bits from now on. */
.p4_end:
mov #2, r0
tst r0, r4
bt .p2_t_end
mov.w @r6+, r1
extu.b r1, r0
mov.b @(r0, r7), r0
shlr8 r1
mov.b r0, @(8, r5)
extu.b r1, r0
mov.b @(r0, r7), r0
mov.b r0, @r5
add #16, r5
.p2_t_end:
mov #1, r0
tst r0, r4
bt .p1_t_end
mov.b @r6+, r0
extu.b r0, r0
mov.b @(r0, r7), r0
rts
mov.b r0, @r5
.p1_t_end:
rts
nop
.size __grey_line1, . - __grey_line1
#endif
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
/***************************************************************************
* __________ __ ___.
* Open \______ \ ____ ____ | | _\_ |__ _______ ___
* Source | _// _ \_/ ___\| |/ /| __ \ / _ \ \/ /
* Jukebox | | ( <_> ) \___| < | \_\ ( <_> > < <
* Firmware |____|_ /\____/ \___ >__|_ \|___ /\____/__/\_ \
* \/ \/ \/ \/ \/
* $Id$
*
* New greyscale framework
* Coldfire assembler routines
*
* This is a generic framework to display 129 shades of grey on low-depth
* bitmap LCDs (Archos b&w, Iriver & Ipod 4-grey) within plugins.
*
* Copyright (C) 2008 Jens Arnold
*
* This program is free software; you can redistribute it and/or
* modify it under the terms of the GNU General Public License
* as published by the Free Software Foundation; either version 2
* of the License, or (at your option) any later version.
*
* This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
* KIND, either express or implied.
*
****************************************************************************/
#include "config.h"
/* Plugins should not normally do this, but we need to check a macro, and
* plugin.h would confuse the assembler. */
.text
.global _grey_line1
.type _grey_line1, @function
#if (LCD_PIXELFORMAT == VERTICAL_PACKING) \
|| (LCD_PIXELFORMAT == VERTICAL_INTERLEAVED)
#if (LCD_DEPTH == 1) || (LCD_PIXELFORMAT == VERTICAL_INTERLEAVED)
#define GREY_BSIZE 8
#elif LCD_DEPTH == 2
#define GREY_BSIZE 4
#endif
/****************************************************************************
* void _grey_line1(int width,
* unsigned char *dst,
* const unsigned char *src,
* const unsigned char *lut);
*/
_grey_line1:
lea.l (-2*4, %sp), %sp
movem.l %d2/%a2, (%sp)
movem.l (2*4+4, %sp), %d2/%a0-%a2
clr.l %d0
move.l %a1, %d1
and.l #1, %d1
beq.s .p1_h_end
move.b (%a1)+, %d0
move.b (%d0.l, %a2), (%a0)
addq.l #GREY_BSIZE, %a0
subq.l #1, %d2
.p1_h_end:
cmp.l #2, %d2
blo.s .p2_t_end
move.l %a1, %d1
and.l #2, %d1
beq.s .p2_h_end
move.w (%a1)+, %d1
move.w %d1, %d0
lsr.l #8, %d0
move.b (%d0.l, %a2), (%a0)
addq.l #GREY_BSIZE, %a0
move.b %d1, %d0
move.b (%d0.l, %a2), (%a0)
addq.l #GREY_BSIZE, %a0
subq.l #2, %d2
.p2_h_end:
subq.l #4, %d2
blo.s .p4_end
.p4_loop:
move.l (%a1)+, %d1
swap %d1
move.w %d1, %d0
lsr.l #8, %d0
move.b (%d0.l, %a2), (%a0)
addq.l #GREY_BSIZE, %a0
move.b %d1, %d0
move.b (%d0.l, %a2), (%a0)
addq.l #GREY_BSIZE, %a0
swap %d1
move.w %d1, %d0
lsr.l #8, %d0
move.b (%d0.l, %a2), (%a0)
addq.l #GREY_BSIZE, %a0
move.b %d1, %d0
move.b (%d0.l, %a2), (%a0)
addq.l #GREY_BSIZE, %a0
subq.l #4, %d2
bhs.s .p4_loop
/* No need to correct the count, we're only testing bits from now on. */
.p4_end:
btst.l #1, %d2
beq.s .p2_t_end
move.w (%a1)+, %d1
move.w %d1, %d0
lsr.l #8, %d0
move.b (%d0.l, %a2), (%a0)
addq.l #GREY_BSIZE, %a0
move.b %d1, %d0
move.b (%d0.l, %a2), (%a0)
addq.l #GREY_BSIZE, %a0
.p2_t_end:
btst.l #0, %d2
beq.s .p1_t_end
move.b (%a1)+, %d0
move.b (%d0.l, %a2), (%a0)
.p1_t_end:
movem.l (%sp), %d2/%a2
lea.l (2*4, %sp), %sp
rts
.size _grey_line1, . - _grey_line1
#endif
|